home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d15
/
gqmail.arc
/
QMAIL.XWS
< prev
Wrap
Text File
|
1990-12-09
|
2KB
|
90 lines
/*
Crosstalk for Windows MarkMail Qmail Automator
version 2.4 11/27/1990
*/
/*
If you are using Qmail, this script assumes that you have
The extended prompts on
*/
STRING RepName, QwkName, DirRep, DirQwk, SaveQwk, MailCmd, Cmd
MailCmd is Arg(2) + " " + Arg(3)
Cmd is Arg(1) + " " + Arg(2) + " " + Arg(3)
If UpCase(Arg(1)) is "MAIL" then Mail is True else Mail is False
--WE'RE DOING MAIL
RepName is NAME+".REP"
QwkName is NAME+".QWK"
DirRep is DirFil+"\"+RepName
DirQwk is DirFil+"\"+QwkName
SaveQwk is DirFil+"\"+inject(QwkName,"1",1)
--SET UP FILE NAMES
-- The language prompt on some boards
wait 10 seconds for '=no?' : If TimeOut then GoTo WatchLoop
else reply 'n q'
--Minimize
--ENABLE THE ABOVE AFTER YOU'VE DETERMINED THAT THE SCRIPT WORKS
LABEL WatchLoop
reply
--THE ABOVE REPLY IS SO THAT YOU CAN ACTUALLY RUN THE SCRIPT AFTER
--YOU HAVE LOGGED ONTO A PCBOARD.
while online
watch for
'first name?' : wait 5 ticks : reply UserID+ " " + Password
'=no?',
'tinue?',
'tinue:',
'stop?',
'(NS)?',
'use (Enter)=no change?',
'More?' : wait 5 ticks : reply
'=yes?' : wait 5 ticks : reply "N"
'Check your mail' : reply "N"
--FOR THE QUICK LOGON FOUND ON SOME PCBOARDS.
'(S)ystem, (Enter)=' : If Mail then Reply MailCmd else reply Cmd:...
Alarm : Halt
--The normal main board prompt or confernce prompt
'Conference Command?',
'Board Command? ' : If Mail then...
Reply MailCmd :...
Wait 10 Ticks else Reply Cmd : Alarm : Halt
-- The mail prompts
'MarkMail Command?',
'<COMMAND>': Reply "D" : Goto GetPacket
endwatch
wend
LABEL GetPacket
Watch for
'[Y]es, [N]o, [G]oodbye When Done? ',
'<DLASK>': Reply "Y" : GoSub DoFiles : Goto SendFiles
'<NO TRANSFER>' : Wait 3 : Goto SendFiles
endwatch
LABEL DoFiles
If Exists(SaveQwk) then Delete SaveQwk
If Exists(DirQwk) then Rename DirQwk,SaveQwk
Message "Renaming old QWK"
Watch for
'(Ctrl-X) Aborts Transfer': Receive QwkName : Alarm : Wait for 'Command'
'<DOWNLOAD>': Receive QwkName : Alarm : Wait for '<COMMAND>'
endwatch
Return
LABEL SendFiles
If exists(DirRep) then{
Reply "U"
Wait 5 ticks
Send RepName
Delete DirRep
Message "Deleting reply file..."
Wait 10 For 'Command' : Reply "G" : Halt
}
else Reply "G" : Halt
end